7795a230f2
* Implement support for `async` functions in Wasmtime This is an implementation of [RFC 2] in Wasmtime which is to support `async`-defined host functions. At a high level support is added by executing WebAssembly code that might invoke an asynchronous host function on a separate native stack. When the host function's future is not ready we switch back to the main native stack to continue execution. There's a whole bunch of details in this commit, and it's a bit much to go over them all here in this commit message. The most important changes here are: * A new `wasmtime-fiber` crate has been written to manage the low-level details of stack-switching. Unixes use `mmap` to allocate a stack and Windows uses the native fibers implementation. We'll surely want to refactor this to move stack allocation elsewhere in the future. Fibers are intended to be relatively general with a lot of type paremters to fling values back and forth across suspension points. The whole crate is a giant wad of `unsafe` unfortunately and involves handwritten assembly with custom dwarf CFI directives to boot. Definitely deserves a close eye in review! * The `Store` type has two new methods -- `block_on` and `on_fiber` which bridge between the async and non-async worlds. Lots of unsafe fiddly bits here as we're trying to communicate context pointers between disparate portions of the code. Extra eyes and care in review is greatly appreciated. * The APIs for binding `async` functions are unfortunately pretty ugly in `Func`. This is mostly due to language limitations and compiler bugs (I believe) in Rust. Instead of `Func::wrap` we have a `Func::wrapN_async` family of methods, and we've also got a whole bunch of `Func::getN_async` methods now too. It may be worth rethinking the API of `Func` to try to make the documentation page actually grok'able. This isn't super heavily tested but the various test should suffice for engaging hopefully nearly all the infrastructure in one form or another. This is just the start though! [RFC 2]: https://github.com/bytecodealliance/rfcs/pull/2 * Add wasmtime-fiber to publish script * Save vector/float registers on ARM too. * Fix a typo * Update lock file * Implement periodically yielding with fuel consumption This commit implements APIs on `Store` to periodically yield execution of futures through the consumption of fuel. When fuel runs out a future's execution is yielded back to the caller, and then upon resumption fuel is re-injected. The goal of this is to allow cooperative multi-tasking with futures. * Fix compile without async * Save/restore the frame pointer in fiber switching Turns out this is another caller-saved register! * Simplify x86_64 fiber asm Take a leaf out of aarch64's playbook and don't have extra memory to load/store these arguments, instead leverage how `wasmtime_fiber_switch` already loads a bunch of data into registers which we can then immediately start using on a fiber's start without any extra memory accesses. * Add x86 support to wasmtime-fiber * Add ARM32 support to fiber crate * Make fiber build file probing more flexible * Use CreateFiberEx on Windows * Remove a stray no-longer-used trait declaration * Don't reach into `Caller` internals * Tweak async fuel to eventually run out. With fuel it's probably best to not provide any way to inject infinite fuel. * Fix some typos * Cleanup asm a bit * Use a shared header file to deduplicate some directives * Guarantee hidden visibility for functions * Enable gc-sections on macOS x86_64 * Add `.type` annotations for ARM * Update lock file * Fix compile error * Review comments
84 lines
2.5 KiB
ArmAsm
84 lines
2.5 KiB
ArmAsm
// A WORD OF CAUTION
|
|
//
|
|
// This entire file basically needs to be kept in sync with itself. It's not
|
|
// really possible to modify just one bit of this file without understanding
|
|
// all the other bits. Documentation tries to reference various bits here and
|
|
// there but try to make sure to read over everything before tweaking things!
|
|
//
|
|
// Also at this time this file is heavily based off the x86_64 file, so you'll
|
|
// probably want to read that one as well.
|
|
|
|
#include "header.h"
|
|
|
|
// fn(top_of_stack(%r0): *mut u8)
|
|
HIDDEN(wasmtime_fiber_switch)
|
|
GLOBL(wasmtime_fiber_switch)
|
|
TYPE(wasmtime_fiber_switch)
|
|
FUNCTION(wasmtime_fiber_switch):
|
|
// Save callee-saved registers
|
|
push {r4-r11,lr}
|
|
|
|
// Swap stacks, recording our current stack pointer
|
|
ldr r4, [r0, #-0x08]
|
|
str sp, [r0, #-0x08]
|
|
mov sp, r4
|
|
|
|
// Restore and return
|
|
pop {r4-r11,lr}
|
|
bx lr
|
|
SIZE(wasmtime_fiber_switch)
|
|
|
|
// fn(
|
|
// top_of_stack(%r0): *mut u8,
|
|
// entry_point(%r1): extern fn(*mut u8, *mut u8),
|
|
// entry_arg0(%r2): *mut u8,
|
|
// )
|
|
HIDDEN(wasmtime_fiber_init)
|
|
GLOBL(wasmtime_fiber_init)
|
|
TYPE(wasmtime_fiber_init)
|
|
FUNCTION(wasmtime_fiber_init):
|
|
adr r3, FUNCTION(wasmtime_fiber_start)
|
|
str r3, [r0, #-0x0c] // => lr
|
|
str r0, [r0, #-0x10] // => r11
|
|
str r1, [r0, #-0x14] // => r10
|
|
str r2, [r0, #-0x18] // => r9
|
|
|
|
add r3, r0, #-0x2c
|
|
str r3, [r0, #-0x08]
|
|
bx lr
|
|
SIZE(wasmtime_fiber_init)
|
|
|
|
FUNCTION(wasmtime_fiber_start):
|
|
.cfi_startproc simple
|
|
// See the x86_64 file for more commentary on what these CFI directives are
|
|
// doing. Like over there note that the relative offsets to registers here
|
|
// match the frame layout in `wasmtime_fiber_switch`.
|
|
//
|
|
// TODO: this is only lightly tested. This gets backtraces in gdb but not
|
|
// at runtime. Perhaps the libgcc at runtime was too old? Doesn't support
|
|
// something here? Unclear. Will need investigation if someone ends up
|
|
// needing this and it still doesn't work.
|
|
.cfi_escape 0x0f, /* DW_CFA_def_cfa_expression */ \
|
|
5, /* the byte length of this expression */ \
|
|
0x7d, 0x00, /* DW_OP_breg14(%sp) + 0 */ \
|
|
0x06, /* DW_OP_deref */ \
|
|
0x23, 0x24 /* DW_OP_plus_uconst 0x24 */
|
|
|
|
.cfi_rel_offset lr, -0x04
|
|
.cfi_rel_offset r11, -0x08
|
|
.cfi_rel_offset r10, -0x0c
|
|
.cfi_rel_offset r9, -0x10
|
|
.cfi_rel_offset r8, -0x14
|
|
.cfi_rel_offset r7, -0x18
|
|
.cfi_rel_offset r6, -0x1c
|
|
.cfi_rel_offset r5, -0x20
|
|
.cfi_rel_offset r4, -0x24
|
|
|
|
mov r1, r11
|
|
mov r0, r9
|
|
blx r10
|
|
.cfi_endproc
|
|
SIZE(wasmtime_fiber_start)
|
|
|
|
FOOTER
|