832666c45e
* Manually rename BasicBlock to BlockPredecessor BasicBlock is a pair of (Ebb, Inst) that is used to represent the basic block subcomponent of an Ebb that is a predecessor to an Ebb. Eventually we will be able to remove this struct, but for now it makes sense to give it a non-conflicting name so that we can start to transition Ebb to represent a basic block. I have not updated any comments that refer to BasicBlock, as eventually we will remove BlockPredecessor and replace with Block, which is a basic block, so the comments will become correct. * Manually rename SSABuilder block types to avoid conflict SSABuilder has its own Block and BlockData types. These along with associated identifier will cause conflicts in a later commit, so they are renamed to be more verbose here. * Automatically rename 'Ebb' to 'Block' in *.rs * Automatically rename 'EBB' to 'block' in *.rs * Automatically rename 'ebb' to 'block' in *.rs * Automatically rename 'extended basic block' to 'basic block' in *.rs * Automatically rename 'an basic block' to 'a basic block' in *.rs * Manually update comment for `Block` `Block`'s wikipedia article required an update. * Automatically rename 'an `Block`' to 'a `Block`' in *.rs * Automatically rename 'extended_basic_block' to 'basic_block' in *.rs * Automatically rename 'ebb' to 'block' in *.clif * Manually rename clif constant that contains 'ebb' as substring to avoid conflict * Automatically rename filecheck uses of 'EBB' to 'BB' 'regex: EBB' -> 'regex: BB' '$EBB' -> '$BB' * Automatically rename 'EBB' 'Ebb' to 'block' in *.clif * Automatically rename 'an block' to 'a block' in *.clif * Fix broken testcase when function name length increases Test function names are limited to 16 characters. This causes the new longer name to be truncated and fail a filecheck test. An outdated comment was also fixed.
50 lines
1.4 KiB
Plaintext
50 lines
1.4 KiB
Plaintext
test regalloc
|
|
target i686
|
|
|
|
; regex: V=v\d+
|
|
; regex: BB=block\d+
|
|
|
|
; The value v9 appears both as the branch control and one of the block arguments
|
|
; in the brnz instruction in block2. It also happens that v7 and v9 are assigned
|
|
; to the same register, so v9 doesn't need to be moved before the brnz.
|
|
;
|
|
; This ended up confusong the constraint solver which had not made a record of
|
|
; the fixed register assignment for v9 since it was already in the correct
|
|
; register.
|
|
function %pr147(i32) -> i32 system_v {
|
|
block0(v0: i32):
|
|
v1 = iconst.i32 0
|
|
v2 = iconst.i32 1
|
|
v3 = iconst.i32 0
|
|
jump block2(v3, v2, v0)
|
|
|
|
; check: $(splitEdge=$BB):
|
|
; check: jump block2($V, $V, v9)
|
|
|
|
block2(v4: i32, v5: i32, v7: i32):
|
|
; check: block2
|
|
v6 = iadd v4, v5
|
|
v8 = iconst.i32 -1
|
|
; v7 is killed here and v9 gets the same register.
|
|
v9 = iadd v7, v8
|
|
; check: v9 = iadd v7, v8
|
|
; Here v9 the brnz control appears to interfere with v9 the block argument,
|
|
; so divert_fixed_input_conflicts() calls add_var(v9), which is ok. The
|
|
; add_var sanity checks got confused when no fixed assignment could be
|
|
; found for v9.
|
|
;
|
|
; We should be able to handle this situation without making copies of v9.
|
|
brnz v9, block2(v5, v6, v9)
|
|
; check: brnz v9, $splitEdge
|
|
jump block3
|
|
|
|
block3:
|
|
return v5
|
|
}
|
|
|
|
function %select_i64(i64, i64, i32) -> i64 {
|
|
block0(v0: i64, v1: i64, v2: i32):
|
|
v3 = select v2, v0, v1
|
|
return v3
|
|
}
|