832666c45e
* Manually rename BasicBlock to BlockPredecessor BasicBlock is a pair of (Ebb, Inst) that is used to represent the basic block subcomponent of an Ebb that is a predecessor to an Ebb. Eventually we will be able to remove this struct, but for now it makes sense to give it a non-conflicting name so that we can start to transition Ebb to represent a basic block. I have not updated any comments that refer to BasicBlock, as eventually we will remove BlockPredecessor and replace with Block, which is a basic block, so the comments will become correct. * Manually rename SSABuilder block types to avoid conflict SSABuilder has its own Block and BlockData types. These along with associated identifier will cause conflicts in a later commit, so they are renamed to be more verbose here. * Automatically rename 'Ebb' to 'Block' in *.rs * Automatically rename 'EBB' to 'block' in *.rs * Automatically rename 'ebb' to 'block' in *.rs * Automatically rename 'extended basic block' to 'basic block' in *.rs * Automatically rename 'an basic block' to 'a basic block' in *.rs * Manually update comment for `Block` `Block`'s wikipedia article required an update. * Automatically rename 'an `Block`' to 'a `Block`' in *.rs * Automatically rename 'extended_basic_block' to 'basic_block' in *.rs * Automatically rename 'ebb' to 'block' in *.clif * Manually rename clif constant that contains 'ebb' as substring to avoid conflict * Automatically rename filecheck uses of 'EBB' to 'BB' 'regex: EBB' -> 'regex: BB' '$EBB' -> '$BB' * Automatically rename 'EBB' 'Ebb' to 'block' in *.clif * Automatically rename 'an block' to 'a block' in *.clif * Fix broken testcase when function name length increases Test function names are limited to 16 characters. This causes the new longer name to be truncated and fail a filecheck test. An outdated comment was also fixed.
158 lines
3.5 KiB
Plaintext
158 lines
3.5 KiB
Plaintext
test regalloc
|
|
target riscv32
|
|
|
|
; Test the coalescer.
|
|
; regex: V=v\d+
|
|
; regex: WS=\s+
|
|
; regex: LOC=%\w+
|
|
; regex: BB=block\d+
|
|
|
|
; This function is already CSSA, so no copies should be inserted.
|
|
function %cssa(i32) -> i32 {
|
|
block0(v0: i32):
|
|
; not: copy
|
|
; v0 is used by the branch and passed as an arg - that's no conflict.
|
|
brnz v0, block1(v0)
|
|
jump block2
|
|
|
|
block2:
|
|
; v0 is live across the branch above. That's no conflict.
|
|
v1 = iadd_imm v0, 7
|
|
jump block1(v1)
|
|
|
|
block1(v10: i32):
|
|
v11 = iadd_imm v10, 7
|
|
return v11
|
|
}
|
|
|
|
function %trivial(i32) -> i32 {
|
|
block0(v0: i32):
|
|
; check: brnz v0, $(splitEdge=$BB)
|
|
brnz v0, block1(v0)
|
|
jump block2
|
|
|
|
block2:
|
|
; not: copy
|
|
v1 = iadd_imm v0, 7
|
|
jump block1(v1)
|
|
|
|
; check: $splitEdge:
|
|
; nextln: $(cp1=$V) = copy.i32 v0
|
|
; nextln: jump block1($cp1)
|
|
|
|
block1(v10: i32):
|
|
; Use v0 in the destination block causes a conflict.
|
|
v11 = iadd v10, v0
|
|
return v11
|
|
}
|
|
|
|
; A value is used as an SSA argument twice in the same branch.
|
|
function %dualuse(i32) -> i32 {
|
|
block0(v0: i32):
|
|
; check: brnz v0, $(splitEdge=$BB)
|
|
brnz v0, block1(v0, v0)
|
|
jump block2
|
|
|
|
block2:
|
|
v1 = iadd_imm v0, 7
|
|
v2 = iadd_imm v1, 56
|
|
jump block1(v1, v2)
|
|
|
|
; check: $splitEdge:
|
|
; check: $(cp1=$V) = copy.i32 v0
|
|
; nextln: jump block1($cp1, v0)
|
|
|
|
block1(v10: i32, v11: i32):
|
|
v12 = iadd v10, v11
|
|
return v12
|
|
}
|
|
|
|
; Interference away from the branch
|
|
; The interference can be broken with a copy at either branch.
|
|
function %interference(i32) -> i32 {
|
|
block0(v0: i32):
|
|
; not: copy
|
|
; check: brnz v0, $(splitEdge=$BB)
|
|
; not: copy
|
|
brnz v0, block1(v0)
|
|
jump block2
|
|
|
|
block2:
|
|
v1 = iadd_imm v0, 7
|
|
; v1 and v0 interfere here:
|
|
v2 = iadd_imm v0, 8
|
|
; check: $(cp0=$V) = copy v1
|
|
; check: jump block1($cp0)
|
|
jump block1(v1)
|
|
|
|
; check: $splitEdge:
|
|
; not: copy
|
|
; nextln: jump block1(v0)
|
|
|
|
block1(v10: i32):
|
|
; not: copy
|
|
v11 = iadd_imm v10, 7
|
|
return v11
|
|
}
|
|
|
|
; A loop where one induction variable is used as a backedge argument.
|
|
function %fibonacci(i32) -> i32 {
|
|
block0(v0: i32):
|
|
v1 = iconst.i32 1
|
|
v2 = iconst.i32 2
|
|
jump block1(v1, v2)
|
|
|
|
; check: $(splitEdge=$BB):
|
|
; check: $(nv11b=$V) = copy.i32 v11
|
|
; not: copy
|
|
; check: jump block1($nv11b, v12)
|
|
|
|
block1(v10: i32, v11: i32):
|
|
; v11 needs to be isolated because it interferes with v10.
|
|
; check: block1(v10: i32 [$LOC], $(nv11a=$V): i32 [$LOC])
|
|
; check: v11 = copy $nv11a
|
|
v12 = iadd v10, v11
|
|
v13 = icmp ult v12, v0
|
|
; check: brnz v13, $splitEdge
|
|
brnz v13, block1(v11, v12)
|
|
jump block2
|
|
|
|
block2:
|
|
return v12
|
|
}
|
|
|
|
; Function arguments passed on the stack aren't allowed to be part of a virtual
|
|
; register, at least for now. This is because the other values in the virtual
|
|
; register would need to be spilled to the incoming_arg stack slot which we treat
|
|
; as belonging to the caller.
|
|
function %stackarg(i32, i32, i32, i32, i32, i32, i32, i32, i32) -> i32 {
|
|
; check: ss0 = incoming_arg 4
|
|
; not: incoming_arg
|
|
block0(v0: i32, v1: i32, v2: i32, v3: i32, v4: i32, v5: i32, v6: i32, v7: i32, v8: i32):
|
|
; check: fill v8
|
|
; not: v8
|
|
jump block1(v8)
|
|
|
|
block1(v10: i32):
|
|
v11 = iadd_imm v10, 1
|
|
return v11
|
|
}
|
|
|
|
function %gvn_unremovable_phi(i32) system_v {
|
|
block0(v0: i32):
|
|
v2 = iconst.i32 0
|
|
jump block2(v2, v0)
|
|
|
|
block2(v3: i32, v4: i32):
|
|
brnz v3, block2(v3, v4)
|
|
jump block3
|
|
|
|
block3:
|
|
v5 = iconst.i32 1
|
|
brnz v3, block2(v2, v5)
|
|
jump block4
|
|
|
|
block4:
|
|
return
|
|
}
|