832666c45e
* Manually rename BasicBlock to BlockPredecessor BasicBlock is a pair of (Ebb, Inst) that is used to represent the basic block subcomponent of an Ebb that is a predecessor to an Ebb. Eventually we will be able to remove this struct, but for now it makes sense to give it a non-conflicting name so that we can start to transition Ebb to represent a basic block. I have not updated any comments that refer to BasicBlock, as eventually we will remove BlockPredecessor and replace with Block, which is a basic block, so the comments will become correct. * Manually rename SSABuilder block types to avoid conflict SSABuilder has its own Block and BlockData types. These along with associated identifier will cause conflicts in a later commit, so they are renamed to be more verbose here. * Automatically rename 'Ebb' to 'Block' in *.rs * Automatically rename 'EBB' to 'block' in *.rs * Automatically rename 'ebb' to 'block' in *.rs * Automatically rename 'extended basic block' to 'basic block' in *.rs * Automatically rename 'an basic block' to 'a basic block' in *.rs * Manually update comment for `Block` `Block`'s wikipedia article required an update. * Automatically rename 'an `Block`' to 'a `Block`' in *.rs * Automatically rename 'extended_basic_block' to 'basic_block' in *.rs * Automatically rename 'ebb' to 'block' in *.clif * Manually rename clif constant that contains 'ebb' as substring to avoid conflict * Automatically rename filecheck uses of 'EBB' to 'BB' 'regex: EBB' -> 'regex: BB' '$EBB' -> '$BB' * Automatically rename 'EBB' 'Ebb' to 'block' in *.clif * Automatically rename 'an block' to 'a block' in *.clif * Fix broken testcase when function name length increases Test function names are limited to 16 characters. This causes the new longer name to be truncated and fail a filecheck test. An outdated comment was also fixed.
93 lines
1.9 KiB
Plaintext
93 lines
1.9 KiB
Plaintext
; Test the custom legalizations.
|
|
test legalizer
|
|
target i686
|
|
target x86_64
|
|
|
|
; regex: V=v\d+
|
|
; regex: BB=block\d+
|
|
|
|
function %cond_trap(i32) {
|
|
block0(v1: i32):
|
|
trapz v1, user67
|
|
return
|
|
; check: block0(v1: i32
|
|
; nextln: $(f=$V) = ifcmp_imm v1, 0
|
|
; nextln: trapif eq $f, user67
|
|
; nextln: return
|
|
}
|
|
|
|
function %cond_trap2(i32) {
|
|
block0(v1: i32):
|
|
trapnz v1, int_ovf
|
|
return
|
|
; check: block0(v1: i32
|
|
; nextln: $(f=$V) = ifcmp_imm v1, 0
|
|
; nextln: trapif ne $f, int_ovf
|
|
; nextln: return
|
|
}
|
|
|
|
function %cond_trap_b1(i32) {
|
|
block0(v1: i32):
|
|
v2 = icmp_imm eq v1, 6
|
|
trapz v2, user7
|
|
return
|
|
; check: block0(v1: i32
|
|
; check: brnz v2, $(new=$BB)
|
|
; check: jump $(trap=$BB)
|
|
; check: $trap:
|
|
; nextln: trap user7
|
|
; check: $new:
|
|
; nextln: return
|
|
}
|
|
|
|
function %cond_trap2_b1(i32) {
|
|
block0(v1: i32):
|
|
v2 = icmp_imm eq v1, 6
|
|
trapnz v2, user9
|
|
return
|
|
; check: block0(v1: i32
|
|
; check: brz v2, $(new=$BB)
|
|
; check: jump $(trap=$BB)
|
|
; check: $trap:
|
|
; nextln: trap user9
|
|
; check: $new:
|
|
; nextln: return
|
|
}
|
|
|
|
function %f32const() -> f32 {
|
|
block0:
|
|
v1 = f32const 0x1.0p1
|
|
; check: $(tmp=$V) = iconst.i32
|
|
; check: v1 = bitcast.f32 $tmp
|
|
return v1
|
|
}
|
|
|
|
function %select_f64(f64, f64, i32) -> f64 {
|
|
block0(v0: f64, v1: f64, v2: i32):
|
|
v3 = select v2, v0, v1
|
|
; check: brnz v2, $(new=$BB)(v0)
|
|
; nextln: jump $new(v1)
|
|
; check: $new(v3: f64):
|
|
; nextln: return v3
|
|
return v3
|
|
}
|
|
|
|
function %f32_min(f32, f32) -> f32 {
|
|
block0(v0: f32, v1: f32):
|
|
v2 = fmin v0, v1
|
|
return v2
|
|
; check: $(vnat=$V) = x86_fmin.f32 v0, v1
|
|
; nextln: jump $(done=$BB)($vnat)
|
|
|
|
; check: $(uno=$BB):
|
|
; nextln: $(vuno=$V) = fadd.f32 v0, v1
|
|
; nextln: jump $(done=$BB)($vuno)
|
|
|
|
; check: $(ueq=$BB):
|
|
; check: $(veq=$V) = bor.f32 v0, v1
|
|
; nextln: jump $(done=$BB)($veq)
|
|
|
|
; check: $done(v2: f32):
|
|
; nextln: return v2
|
|
}
|