832666c45e
* Manually rename BasicBlock to BlockPredecessor BasicBlock is a pair of (Ebb, Inst) that is used to represent the basic block subcomponent of an Ebb that is a predecessor to an Ebb. Eventually we will be able to remove this struct, but for now it makes sense to give it a non-conflicting name so that we can start to transition Ebb to represent a basic block. I have not updated any comments that refer to BasicBlock, as eventually we will remove BlockPredecessor and replace with Block, which is a basic block, so the comments will become correct. * Manually rename SSABuilder block types to avoid conflict SSABuilder has its own Block and BlockData types. These along with associated identifier will cause conflicts in a later commit, so they are renamed to be more verbose here. * Automatically rename 'Ebb' to 'Block' in *.rs * Automatically rename 'EBB' to 'block' in *.rs * Automatically rename 'ebb' to 'block' in *.rs * Automatically rename 'extended basic block' to 'basic block' in *.rs * Automatically rename 'an basic block' to 'a basic block' in *.rs * Manually update comment for `Block` `Block`'s wikipedia article required an update. * Automatically rename 'an `Block`' to 'a `Block`' in *.rs * Automatically rename 'extended_basic_block' to 'basic_block' in *.rs * Automatically rename 'ebb' to 'block' in *.clif * Manually rename clif constant that contains 'ebb' as substring to avoid conflict * Automatically rename filecheck uses of 'EBB' to 'BB' 'regex: EBB' -> 'regex: BB' '$EBB' -> '$BB' * Automatically rename 'EBB' 'Ebb' to 'block' in *.clif * Automatically rename 'an block' to 'a block' in *.clif * Fix broken testcase when function name length increases Test function names are limited to 16 characters. This causes the new longer name to be truncated and fail a filecheck test. An outdated comment was also fixed.
56 lines
1.7 KiB
Plaintext
56 lines
1.7 KiB
Plaintext
test legalizer
|
|
target riscv32
|
|
|
|
; regex: V=v\d+
|
|
|
|
function %icmp_imm_eq(i64) -> b1 {
|
|
block0(v0: i64):
|
|
v1 = icmp_imm eq v0, 0x20202020_10101010
|
|
return v1
|
|
}
|
|
; check: block0($(v0l=$V): i32, $(v0h=$V): i32, $(link=$V): i32):
|
|
; nextln: $(v2l=$V) -> $(v0l)
|
|
; nextln: $(v2h=$V) -> $(v0h)
|
|
; nextln: v0 = iconcat $(v0l), $(v0h)
|
|
; nextln: $(imm_low=$V) = iconst.i32 0x1010_1010
|
|
; nextln: $(imm_high=$V) = iconst.i32 0x2020_2020
|
|
; nextln: $(v3=$V) = icmp eq $(v2l), $(imm_low)
|
|
; nextln: $(v4=$V) = icmp eq $(v2h), $(imm_high)
|
|
; nextln: v1 = band $(v3), $(v4)
|
|
; nextln: return v1, $(link)
|
|
|
|
function %icmp_imm_ne(i64) -> b1 {
|
|
block0(v0: i64):
|
|
v1 = icmp_imm ne v0, 0x33333333_44444444
|
|
return v1
|
|
}
|
|
; check: block0($(v0l=$V): i32, $(v0h=$V): i32, $(link=$V): i32):
|
|
; nextln: $(v2l=$V) -> $(v0l)
|
|
; nextln: $(v2h=$V) -> $(v0h)
|
|
; nextln: v0 = iconcat $(v0l), $(v0h)
|
|
; nextln: $(imm_low=$V) = iconst.i32 0x4444_4444
|
|
; nextln: $(imm_high=$V) = iconst.i32 0x3333_3333
|
|
; nextln: $(v3=$V) = icmp ne $(v2l), $(imm_low)
|
|
; nextln: $(v4=$V) = icmp ne $(v2h), $(imm_high)
|
|
; nextln: v1 = bor $(v3), $(v4)
|
|
; nextln: return v1, $(link)
|
|
|
|
function %icmp_imm_sge(i64) -> b1 {
|
|
block0(v0: i64):
|
|
v1 = icmp_imm sge v0, 0x01020304_05060708
|
|
return v1
|
|
}
|
|
; check: block0($(v0l=$V): i32, $(v0h=$V): i32, $(link=$V): i32):
|
|
; nextln: $(v2l=$V) -> $(v0l)
|
|
; nextln: $(v2h=$V) -> $(v0h)
|
|
; nextln: v0 = iconcat $(v0l), $(v0h)
|
|
; nextln: $(imm_low=$V) = iconst.i32 0x0506_0708
|
|
; nextln: $(imm_high=$V) = iconst.i32 0x0102_0304
|
|
; nextln: $(v3=$V) = icmp sgt $(v2h), $(imm_high)
|
|
; nextln: $(v4=$V) = icmp slt $(v2h), $(imm_high)
|
|
; nextln: $(v5=$V) = icmp uge $(v2l), $(imm_low)
|
|
; nextln: $(v6=$V) = bnot $v4
|
|
; nextln: $(v7=$V) = band $v6, $v5
|
|
; nextln: v1 = bor $(v3), $(v7)
|
|
; nextln: return v1, $(link)
|