test compile
set colocated_libcalls=1
target x86_64

; A function with a big stack frame. This should have a stack probe.

function %big() system_v {
    ss0 = explicit_slot 4097
ebb0:
    return
}
; check: function %big(i64 fp [%rbp]) -> i64 fp [%rbp] system_v {
; nextln:    ss0 = explicit_slot 4097, offset -4113
; nextln:    ss1 = incoming_arg 16, offset -16
; nextln:    sig0 = (i64 [%rax]) -> i64 [%rax] probestack
; nextln:    fn0 = colocated %Probestack sig0
; nextln: 
; nextln:                                 ebb0(v0: i64 [%rbp]):
; nextln: [RexOp1pushq#50]                    x86_push v0
; nextln: [RexOp1copysp#8089]                 copy_special %rsp -> %rbp
; nextln: [RexOp1pu_id#b8,%rax]               v1 = iconst.i64 4112
; nextln: [Op1call_id#e8,%rax]                v2 = call fn0(v1)
; nextln: [RexOp1adjustsp#8029]               adjust_sp_down v2
; nextln: [RexOp1adjustsp_id#8081]            adjust_sp_up_imm 4112
; nextln: [RexOp1popq#58,%rbp]                v3 = x86_pop.i64
; nextln: [Op1ret#c3]                         return v3
; nextln: }


; A function with a small enough stack frame. This shouldn't have a stack probe.

function %small() system_v {
    ss0 = explicit_slot 4096
ebb0:
    return
}

; check: function %small(i64 fp [%rbp]) -> i64 fp [%rbp] system_v {
; nextln:     ss0 = explicit_slot 4096, offset -4112
; nextln:     ss1 = incoming_arg 16, offset -16
; nextln: 
; nextln:                                 ebb0(v0: i64 [%rbp]):
; nextln: [RexOp1pushq#50]                    x86_push v0
; nextln: [RexOp1copysp#8089]                 copy_special %rsp -> %rbp
; nextln: [RexOp1adjustsp_id#d081]            adjust_sp_down_imm 4096
; nextln: [RexOp1adjustsp_id#8081]            adjust_sp_up_imm 4096
; nextln: [RexOp1popq#58,%rbp]                v1 = x86_pop.i64
; nextln: [Op1ret#c3]                         return v1
; nextln: }